BRIX5

// vim:ts=2:sw=2:expandtab

// OSC Lib Example for w/ and w/o timetag

/*

    Make an OSC bundle and send it over SLIP serial

    OSCBundles allow OSCMessages to be grouped together to  preserve the order and completeness of related messages.

    They also allow for timetags to be carried to represent the presentation time of the messages.

*/

#include "OSC/OSCBundle.h"

#include "OSC/OSCBoards.h"

#include "OSC/OSCTiming.h"

#ifdef BOARD_HAS_USB_SERIAL

#include <SLIPEncodedUSBSerial.h>

SLIPEncodedUSBSerial SLIPSerial( thisBoardsSerialUSB );

#else

#include <SLIPEncodedSerial.h>

 SLIPEncodedSerial SLIPSerial(Serial1);

#endif

void setup() {

  //begin SLIPSerial just like Serial

    SLIPSerial.begin(9600);   // set this as high as you can reliably run on your platform

#if ARDUINO >= 100

    while(!Serial)

      ;   // Leonardo bug

#endif

}

void loop(){

    //declare the bundle

    OSCBundle bndl;

    osctime_t timetag;

    //OSCBundle's add' returns the OSCMessage so the message's 'add' can be composed together

    // with timetag

    bndl.add("/analog/0").add((int32_t)adcRead(0, &timetag));

    bndl.add("/analog/0/time").add(timetag);

    bndl.add("/analog/1").add((int32_t)adcRead(1, &timetag));

    bndl.add("/analog/1/time").add(timetag);

    bndl.add("/digital/5").add((digitalRead(5)==HIGH)?"HIGH":"LOW");

    bndl.add("/analog/2").add((int32_t)analogRead(2));

    bndl.add("/analog/3").add((int32_t)analogRead(3));

    bndl.add("/digital/4").add((digitalRead(4)==HIGH)?"HIGH":"LOW");

    SLIPSerial.beginPacket();

    bndl.setTimetag(oscTime());

        bndl.send(SLIPSerial); // send the bytes to the SLIP stream

    SLIPSerial.endPacket(); // mark the end of the OSC Packet

    bndl.empty(); // empty the bundle to free room for a new one

    delay(100);

}